stock Handle:SQL_MakeStdTuple(timeout = 0)
{
    static host[64], user[32], pass[32], db[128];
    static get_type[12], set_type[12];
    
    get_cvar_string("amx_sql_host", host, 63);
    get_cvar_string("amx_sql_user", user, 31);
    get_cvar_string("amx_sql_pass", pass, 31);
    get_cvar_string("amx_sql_type", set_type, 11);
    get_cvar_string("amx_sql_db", db, 127);
    
    SQL_GetAffinity(get_type, 12);
    
    if (!equali(get_type, set_type))
    {
        if (!SQL_SetAffinity(set_type))
        {
            log_amx("Failed to set affinity from %s to %s.", get_type, set_type);
        }
    }
    
    return SQL_MakeDbTuple(host, user, pass, db, timeout);
}

stock SQL_QueryAndIgnore(Handle:db, const queryfmt[], any:...)
{
    static query[4096];
    new Handle:hQuery;
    new ret;
    
    vformat(query, sizeof(query)-1, queryfmt, 3);
    
    hQuery = SQL_PrepareQuery(db, "%s", query);
    
    if (SQL_Execute(hQuery))
    {
        ret = SQL_AffectedRows(hQuery);
    } else {
        ret = -1;
    }
    
    SQL_FreeHandle(hQuery);
    
    return ret;
}

/**
 * Use this for executing a query where you don't care about the result.
 * Returns 0 on failure, 1 on success
 */
stock SQL_SimpleQueryFmt(Handle:db, error[]="", maxlength=0, &rows=0, const fmt[], any:...)
{
    static query_buf[2048];
    vformat(query_buf, 2047, fmt, 6);
    
    new Handle:hQuery = SQL_PrepareQuery(db, "%s", query_buf);
    
    if (!SQL_Execute(hQuery))
    {
        SQL_QueryError(hQuery, error, maxlength);
        SQL_FreeHandle(hQuery);
        return 0;
    }
    
    rows = SQL_NumResults(hQuery);
    
    SQL_FreeHandle(hQuery);
    
    return 1;
}

/**
 * Use this for executing a query where you don't care about the result.
 * Returns 0 on failure, 1 on success
 */
stock SQL_SimpleQuery(Handle:db, const query[], error[]="", maxlength=0, &rows=0)
{
    new Handle:hQuery = SQL_PrepareQuery(db, "%s", query);
    
    if (!SQL_Execute(hQuery))
    {
        SQL_QueryError(hQuery, error, maxlength);
        SQL_FreeHandle(hQuery);
        return 0;
    }
    
    rows = SQL_NumResults(hQuery);
    
    SQL_FreeHandle(hQuery);
    
    return 1;
}

/**
 * This function can be used to find out if a table in a Sqlite database exists.
 * (updated for newer API)
 */
stock bool:sqlite_TableExists(Handle:db, const table[])
{
    new Handle:query = SQL_PrepareQuery(
                    db,
                    "SELECT name FROM sqlite_master WHERE type='table' AND name='%s' LIMIT 1;", 
                    table);
                    
    if (!SQL_Execute(query) || !SQL_NumResults(query))
    {
        SQL_FreeHandle(query);
        return false;
    }
    
    SQL_FreeHandle(query);

    return true;
}

/**
 * For queries which return multiple result sets, this advances to the next 
 * result set if one is available.  Otherwise, the current result set is 
 * destroyed and will no longer be accessible.
 *
 * This function will always return false on SQLite, and when using threaded 
 * queries in MySQL.  Nonetheless, it has the same effect of removing the last 
 * result set.
 *
 * @param query        Query Handle.
 * @return            True on success, false on failure.
 */
native bool:SQL_NextResultSet(Handle:query);

 Показать / Скрыть текст

/**
 * Sets driver affinity.  You can use this to force a particular 
 *  driver implementation.  This will automatically change all SQL
 *  natives in your plugin to be "bound" to the module in question.
 * If no such module is found, it will return 0.  This isn't necessarily bad - 
 *  the user might have typed the wrong driver.  Unless your plugin is built
 *  to handle different driver types at once, you should let this error pass.
 * Note, that using this while you have open handles to another database 
 *  type will cause problems.  I.e., you cannot open a handle, switch
 *  affinity, then close the handle with a different driver.
 * Switching affinity is an O(n*m) operation, where n is the number of
 *  SQL natives and m is the number of used natives in total.
 * Intuitive programmers will note that this causes problems for threaded queries.
 *  You will have to either force your script to work under one affinity, or to 
 *  pack the affinity type into the query data, check it against the current, then
 *  set the new affinity if necessary.  Then, restore the old for safety.
 */

native SQL_SetAffinity(const driver[]);